Сообщество Чайников

Вопрос

У меня такой вопрос: как сделать так, чтобы программа при сворачивании окна сворачивалась не в TaskBar, а в System Tray (где часы, индикатор клавиатуры и т.п.)?

Ответ

На форму помещаешь элемент PictureBox и в него помещаешь ИКОНКУ.
Также делаешь меню: элемент первого уровня — mnuMain (Visible = False)
Элементы второго уровня: mnuMainShow и MnuMainExit
Далее код:
Option Explicit
Private Declare Function Shell_NotifyIcon _
Lib "shell32.dll" Alias _
"Shell_NotifyIconA" (ByVal dwMessage As Long, _
lpData As NOTIFYICONDATA) _
As Long ' функция, которая работает с SysTray
Private Type NOTIFYICONDATA
cbSize As Long
hwnd As Long
uID As Long
uFlags As Long
uCallbackMessage As Long
hIcon As Long
szTip As String * 64
End Type
Private Const NIM_ADD = &H0 ' позволяет добавлять элемент в Tray
Private Const NIM_DELETE = &H2 ' позволяет удалять элемент из Tray
Private Const NIF_MESSAGE = &H1 ' позволяет принимать сообщения
Private Const NIF_ICON = &H2
Private Const NIF_TIP = &H4
'Делаем собственную константу:
Private Const NIF_FLAG = NIF_MESSAGE Or NIF_ICON Or NIF_TIP
' какие события может обрабатывать
Private Const WM_MOUSEMOVE = &H200
Private Const WM_LBUTTONDOWN = &H201
Private Const WM_LBUTTONUP = &H202
Private Const WM_LBUTTONDBLCLK = &H203
Private Const WM_RBUTTONDOWN = &H204
Private Const WM_RBUTTONUP = &H205
Private Const WM_RBUTTONDBLCLK = &H206
Private Const WM_MBUTTONDOWN = &H207
Private Const WM_MBUTTONUP = &H208
Private Const WM_MBUTTONDBLCLK = &H209
Private Icn As NOTIFYICONDATA
Private Sub Form_Resize()
If Me.WindowState = vbMinimized Then ' если форма минимизируется
With Icn
.cbSize = Len(Icn)
.hwnd = Picture1.hwnd
.uID = 1
.uFlags = NIF_FLAG 'вот и наша константа,
' содержащая параметры вызова функции
.uCallbackMessage = WM_MOUSEMOVE
.hIcon = Picture1.Picture
Shell_NotifyIcon NIM_ADD, Icn ' добавляем в Tray
Me.Hide ' прячем саму форму
End With
End If
End Sub
Private Sub mnuMainExit_Click()
Shell_NotifyIcon NIM_DELETE, Icn
Unload Me
End
End Sub
Private Sub mnuMainShow_Click()
Me.WindowState = vbNormal
Me.Show
Shell_NotifyIcon NIM_DELETE, Icn
End Sub
Private Sub Picture1_MouseMove(Button As Integer, _
Shift As Integer, _
X As Single, _
Y As Single)
X = X / Screen.TwipsPerPixelX
Select Case X
Case WM_LBUTTONDOWN
'в эту сточку добавьте код,
'который должен выполниться,
'если нажата левая кнопка мышки
Case WM_RBUTTONDOWN
Me.PopupMenu mnuMain
Case WM_MOUSEMOVE
Case WM_LBUTTONDBLCLK
Case WM_RBUTTONUP
Case WM_RBUTTONDBLCLK
End Select
End Sub

Дмитрий Данелия